#COMPILE EXE
#DIM ALL
#INCLUDE ONCE "DosPrint.inc"
#INCLUDE ONCE "FindDialog.inc"

$CLI  = "get-dlg-loc"
$ARG1 = """dialog caption, all or part"""
$ARG2 = "#12345 (hash followed by dialog handle)"

FUNCTION PBMAIN () AS LONG
    LOCAL dlgList() AS STRING
    LOCAL nbDlg AS LONG
    LOCAL x, y AS LONG
    LOCAL inTxt AS STRING
    LOCAL hD AS DWORD
    LOCAL caption AS STRING

    IF COMMAND$ = "" THEN
        CALL FreeConsole() ' Win32 mode -> hide console
        ?"This utility must be called via the command-line."+$CR+$CR _
        +"Usage:" + $CR + $CLI + $SPC + $ARG1 + $CR _
        +"or " + $CR + $CLI + $SPC + $ARG2 _
        , %MB_ICONINFORMATION, $CLI
        EXIT FUNCTION
    END IF

    IF COMMAND$ = "/?" THEN
        DosPrint "Usage: " + $CLI + $SPC + $ARG1
        DosPrint "    or " + $CLI + $SPC + $ARG2
        EXIT FUNCTION
    END IF

    inTxt = TRIM$(COMMAND$, ANY $SPC+$TAB+$DQ)

    ' Find all dialogs based on inTxt
    REDIM dlgList(0)
    IF LEFT$(inTxt, 1) = "#" THEN
        nbDlg = FindDialog("HND:" + MID$(inTxt,2), BYREF dlgList())
    ELSE
        nbDlg = FindDialog("CAP:" + inTxt, BYREF dlgList())
    END IF

    ' No dialog found
    IF nbDlg = 0 THEN
        DosPrint "No dialog found."
        EXIT FUNCTION
    END IF

    ' More than 1 dialog found
    IF nbDlg > 1 THEN
        DosPrint "Several dialogs found, please specify which one to take:"
        FOR x = 1 TO nbDlg
            DosPrint "  " + dlgList(x-1)
        NEXT
        EXIT FUNCTION
    END IF

    ' Just 1 dialog found > get its information
    hD = VAL(MID$(dlgList(0),2))
    caption = MID$(dlgList(0), INSTR(dlgList(0),":")+1)
    DIALOG GET LOC hD TO x, y
    DosPrint "Dialog found: #"+FORMAT$(hD)+$SPC+$DQ+caption+$DQ
    DosPrint "Location: ("+FORMAT$(x)+","+FORMAT$(y)+")"

END FUNCTION